FormListControl.getItem Method

Article
2014-04-11

Retrieves a FormListItem object for an item in a form list control.

Syntax

public FormListItem getItem(int Idx, [int SubItem])

Run On

Client

Parameters

Idx
Type: int
The zero-based index for an item in a form list control.

SubItem
Type: int
An Integer data type that specifies a sub-item in a form list control.

Return Value

Type: FormListItem Class
A FormListItem object for an item in a form list control.

Examples

The following example shows a call to the getItem method to return a FormListItem object for each item in the form list control. The FormListItem.toString method returns a text string for each item.

The while select statement retrieves account numbers from the CustTable table and then stores the data in a container. The items in the variable are added to the form list control by calling the FormListControl.addItem method.

static void createForm2(Args _args) 
{ 
    Args args; 
    Form form; 
    FormRun formRun; 
    FormBuildDesign formBuildDesign; 
    FormBuildDataSource formBuildDataSource; 
    FormBuildListControl formBuildListControl; 
    FormListControl formListControl; 
    FormListItem formListItem; 
    DictTable dictTable; 
    int idx4; 
    boolean columnadd; 
    str string; 
    str itemTxt; 
    container conAccountNum; 
    CustTable custTable; 
    int numAccounts; 
    int i; 
    int item; 
 
    // Create the form header. 
    form = new Form(); 
 
    // Add data sources to the form. 
    dictTable = new DictTable(tableNum(custTable)); 
    formBuildDataSource = form.addDataSource(dictTable.name()); 
    formBuildDataSource.table(dictTable.id()); 
 
    // Create the form design. 
    formBuildDesign = form.addDesign("Design"); 
    formBuildDesign.caption("myForm"); 
 
    // Add a form list control. 
    formBuildListControl = 
 formBuildDesign.addControl(FormControlType::ListView,"List"); 
    idx4 = formBuildListControl.id(); 
 
    args = new Args(); 
    args.object(form); 
 
    // Create the run-time form. 
    formRun = classfactory.formRunClass(args); 
 
    formRun.run(); 
    formRun.detach(); 
 
    formListControl = formRun.control(idx4); 
 
    // Add an item to the form list control. 
    while select custTable 
        where custTable.AccountNum >= 
            "4000" && custTable.AccountNum <= "4040" 
    { 
        conAccountNum += [[custTable.AccountNum]]; 
    } 
 
    numAccounts = conlen(conAccountNum); 
 
    for(i = 1; i <= numAccounts; i++) 
    { 
        string = conPeek(conAccountNum,i); 
        formListItem = new FormListItem(string); 
        item = formListControl.addItem(formListItem); 
        formListItem = formListControl.getItem(item); 
        itemTxt = formListItem.toString(); 
    } 
}

Share via